Conception d’un récepteur de démarrage infrarouge

//-----------------------------------------------------------------------------
// MIT License
//
// Copyright (c) 2023 Nicolas HEBERT
//
// Permission is hereby granted, free of charge, to any person obtaining a copy
// of this software and associated documentation files (the "Software"), to deal
// in the Software without restriction, including without limitation the rights
// to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
// copies of the Software, and to permit persons to whom the Software is
// furnished to do so, subject to the following conditions:
//
// The above copyright notice and this permission notice shall be included in all
// copies or substantial portions of the Software.
// 
// THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
// IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
// FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
// AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
// LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
// OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
// SOFTWARE.
//-----------------------------------------------------------------------------
//
// Pobot Robotic Sophia Antipolis
//
// Code compatible IR SONY remote control
// 40 KHz main freq.
// decode first 4 characters
// use:
// - key 9: to re-program OFF key
// - key 0: to re-program ON key 
//
// Note: Do not forget to “burn bootloader” with clock set 
//       to “internal at 8MHz” before any programing. Else the timer setting 
//.      Will be incorrect, and the decoder will not decode correctly. 
//
//-----------------------------------------------------------------------------

#include <EEPROM.h>

#define SIGNAL_START_PIN PB4
#define IR_SENSOR_PIN  PB3

#define EEPROM_ADDR_KEY_ON 0
#define EEPROM_ADDR_KEY_OFF 1

static volatile uint8_t code_len, code;

enum KEY_VALUES { OFF, ON, REPROG_OFF, REPROG_ON};
static volatile enum KEY_VALUES key[4];
enum IR_STATES { WAIT_START, ACQ};
static volatile enum IR_STATES ir_state;

void init_timer() {
    // Configure Timer0 at 5kHz (for fuse set as internal clk 8MHz)
    TCCR1 = (1 << CTC1) + 5; // CTC mode + prescaler PCK/16
    // boring part ... look at ATiny datasheet
    TCNT1 = 0; GTCCR = _BV(PSR1);
    OCR1A = 99; OCR1C = 99;
    TCNT1 = 0; GTCCR = 0;
    TIMSK = (1 << OCIE1A);
    // end boring part
}

void code_capture() {
  static uint8_t count = 0;
  if(!digitalRead(IR_SENSOR_PIN)) {
    count++;
  } else {
    // Configure Timer0 5kHz.  internal at 8MHz
    // 0 logic     -> ir@0 for 2-3 pulses, 
    // 1 logic     ->          5-6 pulses, 
    // Start logic ->          11-12 pulses
    if(count > 0){
      if(ir_state == WAIT_START) {
        code_len = 0;
        if(count >= 11 && count <= 12) {
          ir_state = ACQ;
        }
      } else {
        code_len++;
        code = code << 1; // push
        if(count >= 6 && count <= 7)
          code++;
      }
      count = 0;
    }
  }
}

void process_msg() {
  static bool reprog = false;
  if(reprog) {
    if((code & 0xF) != key[REPROG_OFF] &&
       (code & 0xF) != key[REPROG_ON]) {
      noInterrupts(); // needed because we stop the ISR function with a long eeprom write and delay 
      key[ON] = code & 0xF;
      EEPROM.write(EEPROM_ADDR_KEY_ON, key[ON]);
      reprog = false;
      delay(200000); // to slow down the process a little bit
      interrupts();
    }
  } else {
    if((code & 0xF) == key[ON]) {
        digitalWrite(SIGNAL_START_PIN, HIGH);
    } else if((code & 0xF) == key[OFF]){
        digitalWrite(SIGNAL_START_PIN, LOW);
    } else if ((code & 0xF) == key[REPROG_OFF] || 
               (code & 0xF) == key[REPROG_ON]) { // re program mode active
      reprog = true;
    } 
  }
}

ISR(TIMER1_COMPA_vect) {
  code_capture();
  if(code_len == 4) {
    ir_state = WAIT_START;
    process_msg();
  }
}

void setup() {
  pinMode(IR_SENSOR_PIN, INPUT);
  digitalWrite(SIGNAL_START_PIN, LOW);
  pinMode(SIGNAL_START_PIN, OUTPUT);

  key[ON] = EEPROM.read(EEPROM_ADDR_KEY_ON);
  key[OFF] = EEPROM.read(EEPROM_ADDR_KEY_OFF);
  key[REPROG_OFF] = 1; // LSB first, so 8 is 1 (code len 4)
  key[REPROG_ON] = 9;

  init_timer();

  ir_state = WAIT_START;
  sei(); // Enable Int.
}

void loop() {}